Zahlungsavis Faxnummer Fritz Fax

Hallo,

wenn ich in der Zahlungsausgangliste eine "Kreditor Zahlungsdatei" erstelle, bekomme ich ja für die Lieferanten mit mehreren Zahlungsposten eine Zahlungsavis.
Nun möchte ich wenn ich diese Zahlungsavis aufrufe und auf Drucken und den Fritz Faxdrucker auswähle er mir die Nummer automatisch übernimmst. (Als Text beim Fax senden Dialog schreibt er mir schon "Zahlungsavis" rein.

Ist dies üerhaupt möglich? Da ich ja auch z.b. 10 Avise hintereinander hab, müsste er ja für jede Seite bzw. jede neue Avis ein extra Fax erstellen und eine andere nummer übernehmen?

Vielen Dank für eure Hilfe

Schau mal ob Dir das hier hilft:

http://www.avm.de/de/Service/FAQs/FAQ_S ... /3433.php3

Volker

Hallo Wimpp

mit Programmanpassungen ist so etwas sicherlich möglich.

Wir setzen bei uns in der Firma Tobit ein und haben dies realisiert.
Dabei wird einen Durchlauf bei Kreditoren, wo eine Faxnummer hinterlegt ist,
der Beleg gefaxt und bei denen ohne Faxnummer auf Papier gedruckt.

Zuerst müsstest Du abklären, ob Fritz!Fax über Steuerkommandos in den Dokumenten
angesteuert werden kann. Für unser Tobit haben wir z.B. im Report 5001909 Zahlungsavise
diese Kommandos eingebaut,

'@@SERIENFAX@@'
'@@NUMMER '+Faxnummer+'@@'
'@@BETREFF Zahlungsavis ' + VendorName + ' vom ' + FORMAT("Posting Date") + '@@'

Ich habe mal kurz bei AVM http://www.avm.de geschaut, ob so was mit Fritz!Fax auch geht.
In der Handbuch-PDF wird dazu auf die Onlinehilfe von Fritz!Fax verwiesen. Außerdem
soll auf der Programm-CD ein Beispielmakro für Word-Serienbriefe vorhanden sein, die
mit Fritz!Fax versendet werden. Da müsstest Du schauen, wie die das mit welchen Kommandos
gemacht haben.

Siehe auch Beitrag von vnase

Schau mal ob Dir das hier hilft:

http://www.avm.de/de/Service/FAQs/FAQ_S ... /3433.php3

Volker

Also wenn Fritz!Fax Steuerkommandos kennt, gehts an die Umsetzung in Navision.

1. In Tabelle 23 Kreditor ein neues Feld für Faxnummer Buchhaltung angelegt
(Feldnummer > 50000 Typ Text 20 Stellen)
Es geht auch mit dem Standardfeld, aber viele Betriebe haben Abteilungsfaxe

2. Das neue Feld in Form 26 Kreditorenkarte eingefügt.

3. In Tabelle 98 Finanzbuchhaltung-Einrichtung zwei neue Felder angelegt
(Feldnummer > 50000 ZahldateiNr_Temp Code 20
ZahldateiNr_Kreditor_Temp Code 20

4. In Form 256 Zahlungsausgangs Buch.-Blatt folgendes geändert
- globale Variablen angelegt

Code:

Name                            DataType     Subtype   Length
Vendor_Rec               Record   Vendor   
PaymentLine_AccountFax    Record   Payment Line   
PaymentLine_AccountFax2  Record   Payment Line   
AccountFax               Boolean      
ZahlungsAvise_Report         Report   Payment Avis   
ZahlDatei                            Text                        30
Fibu_Einrichtung               Record   General Ledger Setup   


- Im MenuButton Zahlungen ein weiteren MenuItem
"Zahlungsavise drucken / faxen" angelegt und im OnPush-Trigger folgenden Code hinterlegt

Code:

Fibu_Einrichtung.GET;
Fibu_Einrichtung.ZahldateiNr_Temp := '';
Fibu_Einrichtung.ZahldateiNr_Kreditor_Temp := '';
Fibu_Einrichtung.MODIFY;

GenJnlLine.RESET;
GenJnlLine.COPY(Rec);
GenJnlLine.SETRANGE("Bank Payment Type","Bank Payment Type"::Clearing);
GenJnlLine.SETRANGE("Payment File created",TRUE);
IF GenJnlLine.FIND('-') THEN BEGIN
  PaymLedgEntry.RESET;
  PaymLedgEntry.SETCURRENTKEY("Payment No.");
  PaymLedgEntry.SETRANGE(PaymLedgEntry."Payment No.",GenJnlLine."Document No.");
  IF PaymLedgEntry.FIND('-') THEN
    PaymentLine_AccountFax.RESET;
    PaymentLine_AccountFax.SETCURRENTKEY("Payment No.","Account No.");
    PaymentLine_AccountFax.SETFILTER("Payment No.",PaymLedgEntry."Payment No.");
    PaymentLine_AccountFax.SETFILTER("AVIS Letter",'Ja');
    IF PaymentLine_AccountFax.FIND('-') THEN
      REPEAT;
      IF Fibu_Einrichtung.ZahldateiNr_Kreditor_Temp <> PaymentLine_AccountFax."Account No." THEN BEGIN
        Vendor_Rec.GET(PaymentLine_AccountFax."Account No.");
        Fibu_Einrichtung.ZahldateiNr_Temp := PaymLedgEntry."Payment No.";
        Fibu_Einrichtung.ZahldateiNr_Kreditor_Temp := Vendor_Rec."No.";
        Fibu_Einrichtung.MODIFY;

        IF STRLEN(Vendor_Rec."Fax-Nr. Buchhaltung") <> 0 THEN BEGIN
          //Tobit Fax in T78 für Report 5001909 und aktuellen User eintragen

          DruckerAuswahlRec."User ID" := USERID;
          DruckerAuswahlRec."Report ID" := 5001909;
          DruckerAuswahlRec."Printer Name" := 'Tobit FaxWare';

          IF NOT DruckerAuswahlRec.INSERT THEN
            DruckerAuswahlRec.MODIFY;
          COMMIT;

          REPORT.RUNMODAL(REPORT::"Payment Avis",FALSE,FALSE);
          DruckerAuswahlRec.DELETE;
        END ELSE BEGIN
          // Ausgabe auf Drucker (ohne UserName) aus T78
          REPORT.RUNMODAL(REPORT::"Payment Avis",FALSE,FALSE);
        END;
      END;
    UNTIL PaymentLine_AccountFax.NEXT = 0;
END ELSE
  MESSAGE(Text1105400000);


- im Report 5001909 Zahnlungsavise folgendes geändert
Globale Variablen angelegt

Code:

Name   DataType   Subtype   Length
Faxnummer   Text      20
PaymLedgEntry   Record   Payment Ledger Entry   
ZahlDateiNummer   Text      30
ZahlDateiKreditor   Text      30
VendorName   Text      30
CompanyLogo   Record   Company Information   
CompanyName1   Text      50
CompanyName2   Text      50


das erste DataItem Payment Ledger Entry gegen Integer getauscht und dort folgenden Code
hinterlegt

Code:

Integer - OnAfterGetRecord()
GLSetup.GET;
ZahlDateiNummer := GLSetup.ZahldateiNr_Temp;         
ZahlDateiKreditor := GLSetup.ZahldateiNr_Kreditor_Temp;

PaymLedgEntry.SETCURRENTKEY("Payment No.","Execution Date","Bank Account No.");
PaymLedgEntry.SETFILTER("Payment No.",ZahlDateiNummer);
IF PaymLedgEntry.FIND ('-') THEN
  PaymLedgEntry.GET(PaymLedgEntry."Entry No.");

CompanyInfo.GET;


in DataItem PaymLine im OnAfterGetRecord()-Trigger folgenden Code hinterlegt

Code:


AccountNo := "Account No.";
Faxnummer := Vendor."Fax-Nr. Buchhaltung";
VendorName := Vendor.Name;

IF STRLEN(Faxnummer) <> 0 THEN BEGIN
 CompanyLogo.CALCFIELDS(Picture);
  CompanyName1 := CompanyInfo."Firma Name 1";
  CompanyName2 := CompanyInfo."Firma Name 2";
END ELSE BEGIN 
  CLEAR (CompanyLogo);
  CLEAR (CompanyName1);
  CLEAR (CompanyName2);
END;


Dann noch die entsprechenden Steuerkommandos in die Section eintragen
(Wir haben dazu normalerweise eine "unsichtbare" weiße Schrift genommen)

Report Zahlungsavise.jpg

Zu allerletzt noch in der Verwaltung beim Report 5001909 als Standarddrucker den
Papierdrucker eintragen.

Dann sollte es funktionieren

MfG
Christian

Du hast keine ausreichende Berechtigung, um die Dateianhänge dieses Beitrags anzusehen.